From 5da0a971d541471cb72c9435bbdcaf39d7d28a3a Mon Sep 17 00:00:00 2001
From: Stefan Helmert <helst_listen@aol.de>
Date: Wed, 17 Apr 2013 09:57:47 -0500
Subject: [PATCH] The internal BOM generator has bugs. I designed an XSL
 script, which converts the generated XML Partlist into a CSV file for Libre
 Office or Open Office.  It is very easy to use. You can specify it as a
 plugin for Eeshema netlist generator.

It searches for all field names, generates the table headings accounting for all fields found in any part.
Then stuffs all the parts rows according to proper fields.
---
 eeschema/plugins/CMakeLists.txt | 30 +++++++-----
 eeschema/plugins/bom2csv.xsl    | 85 +++++++++++++++++++++++++++++++++
 2 files changed, 102 insertions(+), 13 deletions(-)
 create mode 100644 eeschema/plugins/bom2csv.xsl

diff --git a/eeschema/plugins/CMakeLists.txt b/eeschema/plugins/CMakeLists.txt
index 1dfbf6ebcd..ebc2aed1b4 100644
--- a/eeschema/plugins/CMakeLists.txt
+++ b/eeschema/plugins/CMakeLists.txt
@@ -1,14 +1,18 @@
-if(UNIX)
-    add_definitions(-D__UNIX__)
-endif(UNIX)
-
-# add_executable(netlist_form_pads-pcb netlist_form_pads-pcb.cpp)
-# install(TARGETS netlist_form_pads-pcb   DESTINATION ${KICAD_PLUGINS}  COMPONENT binary)
-
-# install the *.xsl file(s), user will need to install 'xsltproc' and setup
+# Install the *.xsl file(s), user will need to install 'xsltproc' and setup
 # EESCHEMA's netlist plugins
-install( FILES
-                netlist_form_pads-pcb.xsl
-         DESTINATION ${KICAD_PLUGINS}
-         COMPONENT binary
-         )
+# See chapter 14 of eeschema.pdf
+
+
+set( xsl_lst
+    bom2csv.xsl
+    bom_cvs.xsl
+    netlist_form_cadstar-RINF.xsl
+    netlist_form_cadstar.xsl
+    netlist_form_OrcadPcb2.xsl
+    netlist_form_pads-pcb.xsl
+    )
+
+install( FILES ${xsl_lst}
+    DESTINATION ${KICAD_PLUGINS}
+    COMPONENT binary
+    )
diff --git a/eeschema/plugins/bom2csv.xsl b/eeschema/plugins/bom2csv.xsl
new file mode 100644
index 0000000000..3140609928
--- /dev/null
+++ b/eeschema/plugins/bom2csv.xsl
@@ -0,0 +1,85 @@
+<!--XSL style sheet to convert EESCHEMA XML Partlist Format to CSV BOM Format
+    Copyright (C) 2013, Stefan Helmert.
+    GPL v2.
+
+    Functionality:
+        Generation of csv table with table head of all existing field names
+        and correct assigned cell entries
+
+    How to use this is explained in eeschema.pdf chapter 14.  You enter a command line into the
+    netlist exporter using a new (custom) tab in the netlist export dialog.  The command is
+    similar to
+        on Windows:
+            xsltproc -o "%O.csv" "C:\Program Files (x86)\KiCad\bin\plugins\bom2csv.xsl" "%I"
+        on Linux:
+            xsltproc -o "%O.csv" /usr/local/lib/kicad/plugins/bom2csv.xsl "%I"
+
+    Instead of "%O.csv" you can alternatively use "%O" if you will supply your own file extension when
+    prompted in the UI.  The double quotes are there to account for the possibility of space(s)
+    in the filename.
+-->
+
+<!DOCTYPE xsl:stylesheet [
+  <!ENTITY nl  "&#xd;&#xa;">    <!--new line CR, LF, or LF, your choice -->
+]>
+
+
+<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
+    <xsl:output method="text"/>
+
+    <!-- for table head and empty table fields-->
+    <xsl:key name="headentr" match="field" use="@name"/>
+
+    <!-- main part -->
+    <xsl:template match="/export">
+        <xsl:text>Reference, Value, Footprint, Datasheet</xsl:text>
+
+            <!-- find all existing table head entries and list each one once -->
+            <xsl:for-each select="components/comp/fields/field[generate-id(.) = generate-id(key('headentr',@name)[1])]">
+                <xsl:text>, </xsl:text>
+                <xsl:value-of select="@name"/>
+            </xsl:for-each>
+            <xsl:text>&nl;</xsl:text>
+
+        <!-- all table entries -->
+        <xsl:apply-templates select="components/comp"/>
+    </xsl:template>
+
+    <!-- the table entries -->
+    <xsl:template match="components/comp">
+        <xsl:value-of select="@ref"/><xsl:text>,</xsl:text>
+        <xsl:value-of select="value"/><xsl:text>,</xsl:text>
+        <xsl:value-of select="footprint"/><xsl:text>,</xsl:text>
+        <xsl:value-of select="datasheet"/>
+        <xsl:apply-templates select="fields"/>
+        <xsl:text>&nl;</xsl:text>
+    </xsl:template>
+
+    <!-- table entries with dynamic table head -->
+    <xsl:template match="fields">
+
+        <!-- remember current fields section -->
+        <xsl:variable name="fieldvar" select="field"/>
+
+        <!-- for all existing head entries -->
+        <xsl:for-each select="/export/components/comp/fields/field[generate-id(.) = generate-id(key('headentr',@name)[1])]">
+            <xsl:variable name="allnames" select="@name"/>
+            <xsl:text>,</xsl:text>
+
+            <!-- for all field entries in the remembered fields section -->
+            <xsl:for-each select="$fieldvar">
+
+                <!-- only if this field entry exists in this fields section -->
+                <xsl:if test="@name=$allnames">
+                    <!-- content of the field -->
+                    <xsl:value-of select="."/>
+                </xsl:if>
+                <!--
+                    If it does not exist, use an empty cell in output for this row.
+                    Every non-blank entry is assigned to its proper column.
+                -->
+            </xsl:for-each>
+        </xsl:for-each>
+    </xsl:template>
+
+ </xsl:stylesheet>