{ pkgs }:
let
  binPath = with pkgs;
    lib.makeBinPath [
      yarn2nix
      bundix
      coreutils
      diffutils
      nix-prefetch-git
      gnused
      jq
    ];
in pkgs.runCommand "mastodon-update-script" {
  nativeBuildInputs = [ pkgs.makeWrapper ];

  meta = {
    maintainers = with pkgs.lib.maintainers; [ happy-river ];
    description =
      "Utility to generate Nix expressions for Mastodon's dependencies";
    platforms = pkgs.lib.platforms.unix;
  };
} ''
  mkdir -p $out/bin
  cp ${./update.sh} $out/bin/update.sh
  patchShebangs $out/bin/update.sh
  wrapProgram $out/bin/update.sh --prefix PATH : ${binPath}
''
