jiti-meet/android/build.gradle

// Top-level build file where you can add configuration options common to all
// sub-projects/modules.

buildscript {
    repositories {
        jcenter()
        maven { url 'https://maven.google.com' }
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:3.0.0-alpha9'

        // NOTE: Do not place your application dependencies here; they belong
        // in the individual module build.gradle files.
    }
}

allprojects {
    repositories {
        mavenLocal()
        jcenter()
        maven {
            // Google's maven repository, required for AppCompat
            url "https://maven.google.com"
        }
        maven {
            // All of React Native (JS, Obj-C sources, Android binaries) is
            // installed from npm.
            url "$rootDir/../node_modules/react-native/android"
        }
    }
}

ext {
    compileSdkVersion = 25
    buildToolsVersion = "25.0.3"
    minSdkVersion    = 16
    targetSdkVersion = 25
}

// Force the version of the Android build tools we have chosen on all
// subprojects. The forcing was introduced for react-native and the third-party
// modules that we utilize such as react-native-background-timer.
subprojects { subproject ->
    afterEvaluate{
        if (subproject.plugins.hasPlugin('android')
                || subproject.plugins.hasPlugin('android-library')) {
            android {
                buildToolsVersion rootProject.ext.buildToolsVersion
            }
        }
    }
}