Remove old packaging files
This commit is contained in:
Chris Pavlina
parent
34f223a707
commit
a27ad2beca
|
|
@ -1,28 +0,0 @@
|
|||
;Additional text definitions for Dutch
|
||||
|
||||
;File name of license file
|
||||
LicenseLangString MUILicense ${LANG_DUTCH} "..\COPYRIGHT.txt"
|
||||
|
||||
;Component option
|
||||
LangString TITLE_SEC01 ${LANG_DUTCH} "Hoofdprogramma"
|
||||
LangString TITLE_SEC02 ${LANG_DUTCH} "Bibliotheken en componenten"
|
||||
LangString TITLE_SEC03 ${LANG_DUTCH} "Voorbeeld projecten"
|
||||
LangString TITLE_SEC04 ${LANG_DUTCH} "Help bestanden"
|
||||
|
||||
;Component option descriptions
|
||||
LangString DESC_SEC01 ${LANG_DUTCH} "Hoofdprogramma bestanden."
|
||||
LangString DESC_SEC02 ${LANG_DUTCH} "Libraries and components are required unless they have been previously installed."
|
||||
LangString DESC_SEC03 ${LANG_DUTCH} "Verschillende voorbeelden en tutorials."
|
||||
LangString DESC_SEC04 ${LANG_DUTCH} "Help bestanden in pdf formaat."
|
||||
|
||||
;General messages
|
||||
LangString WINGS3D_PROMPT ${LANG_DUTCH} "Voor het bewerken of creeeren van 3D modellen moet u Wings3D installeren. \
|
||||
Wings3D en de gebruikershandleiding kunt u vrij downloaden van de Wings3D webpagina Check this box to open the Wings3D web page"
|
||||
|
||||
LangString UNINST_PROMPT ${LANG_DUTCH} "Are you sure you want to completely remove $(^Name) and all of its components? $\n\
|
||||
This will also remove all modified and new files, libraries and modules in the program directory"
|
||||
|
||||
LangString UNINST_SUCCESS ${LANG_DUTCH} "$(^Name) was succesvol verwijderd van uw computer."
|
||||
LangString INSTALLER_RUNNING ${LANG_DUTCH} "De installer is al actief."
|
||||
LangString UNINSTALLER_RUNNING ${LANG_DUTCH} "De uninstaller is al actief."
|
||||
LangString ALREADY_INSTALLED ${LANG_DUTCH} "${PRODUCT_NAME} is al geinstalleerd. Installatie van dit pakket overschrijft de bestaande versie. Wilt u doorgaan?"
|
||||
|
|
@ -1,28 +0,0 @@
|
|||
;Additional text definitions for English
|
||||
|
||||
;File name of license file
|
||||
LicenseLangString MUILicense ${LANG_ENGLISH} "..\COPYRIGHT.txt"
|
||||
|
||||
;Component option
|
||||
LangString TITLE_SEC01 ${LANG_ENGLISH} "Main application"
|
||||
LangString TITLE_SEC02 ${LANG_ENGLISH} "Libraries and components"
|
||||
LangString TITLE_SEC03 ${LANG_ENGLISH} "Demonstration projects"
|
||||
LangString TITLE_SEC04 ${LANG_ENGLISH} "Help files"
|
||||
|
||||
;Component option descriptions
|
||||
LangString DESC_SEC01 ${LANG_ENGLISH} "Main application files."
|
||||
LangString DESC_SEC02 ${LANG_ENGLISH} "Libraries and components are required unless they have been previously installed."
|
||||
LangString DESC_SEC03 ${LANG_ENGLISH} "Some demonstration projects and tutorials."
|
||||
LangString DESC_SEC04 ${LANG_ENGLISH} "Help files in pdf format."
|
||||
|
||||
;General messages
|
||||
LangString WINGS3D_PROMPT ${LANG_ENGLISH} "To edit or create 3D object models you need to install Wings3D. \
|
||||
Wings3D and user manual can be download free from the Wings3D web page Check this box to open the Wings3D web page"
|
||||
|
||||
LangString UNINST_PROMPT ${LANG_ENGLISH} "Are you sure you want to completely remove $(^Name) and all of its components? $\n\
|
||||
This will also remove all modified and new files, libraries and modules in the program directory"
|
||||
|
||||
LangString UNINST_SUCCESS ${LANG_ENGLISH} "$(^Name) was successfully removed from your computer."
|
||||
LangString INSTALLER_RUNNING ${LANG_ENGLISH} "The installer is already running."
|
||||
LangString UNINSTALLER_RUNNING ${LANG_ENGLISH} "The uninstaller is already running."
|
||||
LangString ALREADY_INSTALLED ${LANG_ENGLISH} "${PRODUCT_NAME} is already installed. Install this package will overwrite existing files. Do you want to continue?"
|
||||
|
|
@ -1,31 +0,0 @@
|
|||
;Additional text definitions for French
|
||||
;These text definition have been translated from English using an automated translation tool
|
||||
;Please correct as required
|
||||
|
||||
;file name of license file
|
||||
LicenseLangString MUILicense ${LANG_FRENCH} "..\COPYRIGHT.txt"
|
||||
|
||||
;Component options
|
||||
LangString TITLE_SEC01 ${LANG_FRENCH} "Application principale"
|
||||
LangString TITLE_SEC02 ${LANG_FRENCH} "Bibliothèques et composants"
|
||||
LangString TITLE_SEC03 ${LANG_FRENCH} "Demos"
|
||||
LangString TITLE_SEC04 ${LANG_FRENCH} "Dossiers d'aide"
|
||||
|
||||
;Component option descriptions
|
||||
LangString DESC_SEC01 ${LANG_FRENCH} "Dossiers de base."
|
||||
LangString DESC_SEC02 ${LANG_FRENCH} "Les bibliothèques sont nécessaires à moins d'avoir été précédemment installées."
|
||||
LangString DESC_SEC03 ${LANG_FRENCH} "Quelques dossiers de demonstration."
|
||||
LangString DESC_SEC04 ${LANG_FRENCH} "Dossiers d'aide."
|
||||
|
||||
;General messages
|
||||
LangString WINGS3D_PROMPT ${LANG_FRENCH} "Pour éditer ou créer des modèles 3D des modules PCB, vous devez installer Wings3D. \
|
||||
Wings3D et manuel d'utilisateur peuvent être téléchargement librement de la page Web de Wings3D.\
|
||||
Cochez cette boîte pour acceder à la page Web de Wings3D."
|
||||
|
||||
LangString UNINST_PROMPT ${LANG_FRENCH} "Êtes-vous sûr de vouloir enlever complètement ${PRODUCT_NAME} et tous ses composants ? $\n\
|
||||
Ceci enlèvera également tous les dossiers, bibliothèques et modules modifiés et nouveaux dans le repertoire $(^name)"
|
||||
|
||||
LangString UNINST_SUCCESS ${LANG_FRENCH} "$(^Name) a été avec succès enlevé à partir de votre ordinateur."
|
||||
LangString INSTALLER_RUNNING ${LANG_FRENCH} "L'installateur fonctionne déjà."
|
||||
LangString UNINSTALLER_RUNNING ${LANG_FRENCH} "Le desinstalleur fonctionne déjà."
|
||||
LangString ALREADY_INSTALLED ${LANG_FRENCH} "${PRODUCT_NAME} est déjà installé. Installer ce paquet remplacera les dossiers existants. Voulez-vous continuer ?"
|
||||
Binary file not shown.
|
|
@ -1,31 +0,0 @@
|
|||
;Additional text definitions for Italian
|
||||
;These text definition have been translated from English using an automated translation tool
|
||||
;Please correct as required
|
||||
|
||||
;File name of license file
|
||||
LicenseLangString MUILicense ${LANG_ITALIAN} "..\COPYRIGHT.txt"
|
||||
|
||||
;Component option
|
||||
LangString TITLE_SEC01 ${LANG_ITALIAN} "Applicazione principale"
|
||||
LangString TITLE_SEC02 ${LANG_ITALIAN} "Biblioteche e componenti"
|
||||
LangString TITLE_SEC03 ${LANG_ITALIAN} "Progetti Demostration"
|
||||
LangString TITLE_SEC04 ${LANG_ITALIAN} "Lime di aiuto"
|
||||
|
||||
;Component option descriptions
|
||||
LangString DESC_SEC01 ${LANG_ITALIAN} "Lime di applicazione principale."
|
||||
LangString DESC_SEC02 ${LANG_ITALIAN} "Le biblioteche ed i componenti sono richiesti a meno che precedentemente siano state installate."
|
||||
LangString DESC_SEC03 ${LANG_ITALIAN} "Alcuni progetti e lezioni private di demostration."
|
||||
LangString DESC_SEC04 ${LANG_ITALIAN} "Lime di aiuto."
|
||||
|
||||
;General messages
|
||||
LangString WINGS3D_PROMPT ${LANG_ITALIAN} "Per pubblicare o generare i modelli che dell'oggetto 3D dovete installare Wings3D. \
|
||||
Wings3D ed il manuale di utente possono provenire trasferimento dal sistema centrale verso i satelliti liberamente dal Web \
|
||||
page di Wings3D. Controlli questa scatola per aprire il Web page di Wings3D."
|
||||
|
||||
LangString UNINST_PROMPT ${LANG_ITALIAN} "Siete sicuri voi desiderate completamente rimuovere $(^name) e tutti i relativi componenti? $\n\
|
||||
Ciò inoltre rimuoverà tutti i lime, biblioteche e moduli modificati e nuovi nell'indice di programma"
|
||||
|
||||
LangString UNINST_SUCCESS ${LANG_ITALIAN} "$(^Name) con successo è stato rimosso dal vostro calcolatore."
|
||||
LangString INSTALLER_RUNNING ${LANG_ITALIAN} "L'installatore già sta funzionando."
|
||||
LangString UNINSTALLER_RUNNING ${LANG_ITALIAN} "Il uninstaller già sta funzionando."
|
||||
LangString ALREADY_INSTALLED ${LANG_ITALIAN} "${product_name} già è installato. Installi questo pacchetto scriverà sopra le lime attuali. Desiderate continuare?"
|
||||
|
|
@ -1,28 +0,0 @@
|
|||
;Additional text definitions for Japanese
|
||||
|
||||
;File name of license file
|
||||
LicenseLangString MUILicense ${LANG_JAPANESE} "..\COPYRIGHT.txt"
|
||||
|
||||
;Component option
|
||||
LangString TITLE_SEC01 ${LANG_JAPANESE} "メイン アプリケーション"
|
||||
LangString TITLE_SEC02 ${LANG_JAPANESE} "ライブラリとコンポーネント"
|
||||
LangString TITLE_SEC03 ${LANG_JAPANESE} "デモンストレーション プロジェクト"
|
||||
LangString TITLE_SEC04 ${LANG_JAPANESE} "ヘルプ ファイル"
|
||||
|
||||
;Component option descriptions
|
||||
LangString DESC_SEC01 ${LANG_JAPANESE} "メイン アプリケーション ファイル"
|
||||
LangString DESC_SEC02 ${LANG_JAPANESE} "ライブラリとコンポーネントは以前インストールされていない場合必要です。"
|
||||
LangString DESC_SEC03 ${LANG_JAPANESE} "デモンストレーションファイルとチュートリアル"
|
||||
LangString DESC_SEC04 ${LANG_JAPANESE} "PDF形式のヘルプファイル"
|
||||
|
||||
;General messages
|
||||
LangString WINGS3D_PROMPT ${LANG_JAPANESE} "3Dオブジェクトモデルの作成、編集を行うためには Wings3Dをインストールする必要があります。\
|
||||
Wings3D とユーザーマニュアルは、このボックスにチェックを入れて Wings3D ウェブページ を開くことでダウンロードできます。"
|
||||
|
||||
LangString UNINST_PROMPT ${LANG_JAPANESE} "$(^Name) と全てのコンポーネントを完全に削除します。宜しいですか $\n\
|
||||
この操作は全ての新しいファイル、修正されたファイル、プログラムディレクトリ中のライブラリとモジュールも削除します。"
|
||||
|
||||
LangString UNINST_SUCCESS ${LANG_JAPANESE} "$(^Name) はあなたのコンピュータから完全に削除されました。"
|
||||
LangString INSTALLER_RUNNING ${LANG_JAPANESE} "インストーラは既に起動されています。"
|
||||
LangString UNINSTALLER_RUNNING ${LANG_JAPANESE} "アンインストーラは既に起動されています。"
|
||||
LangString ALREADY_INSTALLED ${LANG_JAPANESE} "${PRODUCT_NAME} は既にインストールされています。このパッケージインストールは既存のファイルを上書きします。作業を続けますか？"
|
||||
|
|
@ -1,28 +0,0 @@
|
|||
;Additional text definitions for Polish
|
||||
|
||||
;File name of license file
|
||||
LicenseLangString MUILicense ${LANG_POLISH} "..\COPYRIGHT.txt"
|
||||
|
||||
;Component option
|
||||
LangString TITLE_SEC01 ${LANG_POLISH} "Pliki aplikacji"
|
||||
LangString TITLE_SEC02 ${LANG_POLISH} "Biblioteki i elementy"
|
||||
LangString TITLE_SEC03 ${LANG_POLISH} "Przykładowe projekty"
|
||||
LangString TITLE_SEC04 ${LANG_POLISH} "Pliki pomocy."
|
||||
|
||||
;Component option descriptions
|
||||
LangString DESC_SEC01 ${LANG_POLISH} "Główne pliki aplikacji."
|
||||
LangString DESC_SEC02 ${LANG_POLISH} "Biblioteki i elementy są potrzebne jeżeli wcześniej nie zostały zainstalowane."
|
||||
LangString DESC_SEC03 ${LANG_POLISH} "Kilka przykładowych projektów i tutoriali."
|
||||
LangString DESC_SEC04 ${LANG_POLISH} "Pliki pomocy."
|
||||
|
||||
;General messages
|
||||
LangString WINGS3D_PROMPT ${LANG_POLISH} "Aby edytować lub tworzyć modele obiektów 3D musisz zainstalować Wings3D. \
|
||||
Wings3D oraz instrukcja obsługi mogą zostać pobrane za darmo ze strony Wings3D. Zaznacz tę opcję, aby otworzyć stronę główną Wings3D"
|
||||
|
||||
LangString UNINST_PROMPT ${LANG_POLISH} "Czy jesteś pewny, że chcesz usunąć $(^Name) i jego wszystkie komponenty? $\n\
|
||||
Zostaną również usunięte wszystkie zmodyfikowane i nowe pliki, biblioteki i moduły znajdujące się w katalogu programu"
|
||||
|
||||
LangString UNINST_SUCCESS ${LANG_POLISH} "$(^Name) został pomyślnie usunięty z twojego komputera."
|
||||
LangString INSTALLER_RUNNING ${LANG_POLISH} "Instalator jest już uruchomiony."
|
||||
LangString UNINSTALLER_RUNNING ${LANG_POLISH} "Deinstalator jest już uruchomiony."
|
||||
LangString ALREADY_INSTALLED ${LANG_POLISH} "${PRODUCT_NAME} jest już zainstalowany. Ponowna instalacja nadpisze istniejące pliki. Czy kontynuować?"
|
||||
|
|
@ -1,30 +0,0 @@
|
|||
;Additional text definitions for Portuguese
|
||||
;These text definition have been translated from English using an automated translation tool
|
||||
;Please correct as required
|
||||
|
||||
;File name of license file
|
||||
LicenseLangString MUILicense ${LANG_PORTUGUESE} "..\COPYRIGHT.txt"
|
||||
|
||||
;Component option
|
||||
LangString TITLE_SEC01 ${LANG_PORTUGUESE} "Aplicativo principal"
|
||||
LangString TITLE_SEC02 ${LANG_PORTUGUESE} "Bibliotecas e componentes"
|
||||
LangString TITLE_SEC03 ${LANG_PORTUGUESE} "Projetos de Demostração"
|
||||
LangString TITLE_SEC04 ${LANG_PORTUGUESE} "Arquivos de ajuda"
|
||||
|
||||
;Component option descriptions
|
||||
LangString DESC_SEC01 ${LANG_PORTUGUESE} "Arquivos do aplicativo principal."
|
||||
LangString DESC_SEC02 ${LANG_PORTUGUESE} "As bibliotecas e os componentes são necessários, a menos se já foram instalados previamente."
|
||||
LangString DESC_SEC03 ${LANG_PORTUGUESE} "Alguns projetos e tutoriais de demonstração."
|
||||
LangString DESC_SEC04 ${LANG_PORTUGUESE} "Arquivos de ajuda."
|
||||
|
||||
;General messages
|
||||
LangString WINGS3D_PROMPT ${LANG_PORTUGUESE} "Para editar ou criar modelos de objetos 3D você necessita instalar o Wings3D. \
|
||||
Wings3D e o manual de usuário podem ser baixados livremente da Web page do Wings3D. Marque esta caixa para abrir a Web page do Wings3D."
|
||||
|
||||
LangString UNINST_PROMPT ${LANG_PORTUGUESE} "Você está certo que quer remover completamente $(^Name) e todos seus componentes? $\n\
|
||||
Isto removerá também todos os arquivos, bibliotecas e módulos modificados, e novos no diretório do programa"
|
||||
|
||||
LangString UNINST_SUCCESS ${LANG_PORTUGUESE} "$(^Name) foi removido com sucesso de seu computador."
|
||||
LangString INSTALLER_RUNNING ${LANG_PORTUGUESE} "O instalador já está executando."
|
||||
LangString UNINSTALLER_RUNNING ${LANG_PORTUGUESE} "O uninstaller já está executando."
|
||||
LangString ALREADY_INSTALLED ${LANG_PORTUGUESE} "${product_name} já está instalado. Instalar este pacote irá sobrepor os arquivos existentes. Você quer continuar?"
|
||||
|
|
@ -1,30 +0,0 @@
|
|||
;Additional text definitions for French
|
||||
|
||||
;file name of license file
|
||||
LicenseLangString MUILicense ${LANG_RUSSIAN} "..\COPYRIGHT.txt"
|
||||
|
||||
;component option
|
||||
LangString TITLE_SEC01 ${LANG_RUSSIAN} "Ãëàâíàÿ ïðîãðàììà"
|
||||
LangString TITLE_SEC02 ${LANG_RUSSIAN} "Àðõèâû è êîìïîíåíòû"
|
||||
LangString TITLE_SEC03 ${LANG_RUSSIAN} "Ïðîåêòû äåìîíñòðàöèè"
|
||||
LangString TITLE_SEC04 ${LANG_RUSSIAN} "Àðõèâû ïîìîùè"
|
||||
|
||||
;component option descriptions
|
||||
LangString DESC_SEC01 ${LANG_RUSSIAN} "Àðõèâû ãëàâíîé ïðîãðàììû."
|
||||
LangString DESC_SEC02 ${LANG_RUSSIAN} "Àðõèâû è êîìïîíåíòû íåîáõîäèìû åñëè îíè ðàíåå íå óñòàíîâèòü."
|
||||
LangString DESC_SEC03 ${LANG_RUSSIAN} "Íåêîòîðûå ïðîåêòû è êîíñóëüòàöèè äåìîíñòðàöèè."
|
||||
LangString DESC_SEC04 ${LANG_RUSSIAN} "Àðõèâû ïîìîùè."
|
||||
|
||||
;warning messages
|
||||
LangString WINGS3D_PROMPT ${LANG_RUSSIAN} "Ðåäàêòèðîâàòü èëè ñîçäàâàòü ìîäåëè ïðåäìåòà, êîòîð 3D âû óñòàíîâèòü Wings3D. \
|
||||
Wings3D è ðóêîâîäñòâî ïîòðåáèòåëÿ ìîãóò áûòü download ñâîáîäíî îò ïðîâåðêè web page Wings3D ýòà êîðîáêà äëÿ òîãî ÷òîáû \
|
||||
ðàñêðûòü web page Wings3D."
|
||||
|
||||
LangString UNINST_PROMPT ${LANG_RUSSIAN} "Âû óâåðåíû âû õîòèòå âïîëíå èçâëå÷ü $(^name) è âåñü èç ñâîèõ êîìïîíåíòîâ? $\n \
|
||||
Ýòî òàêæå èçâëåêàåò âñå äîðàáîòàííûå è íîâûå àðõèâû, àðõèâû è ìîäóëè â äèðåêòîðèè ïðîãðàììû"
|
||||
|
||||
LangString UNINST_SUCCESS ${LANG_RUSSIAN} "$(^name) óñïåøíî èçâëåêëîñü îò âàøåãî êîìïüþòåðà."
|
||||
LangString INSTALLER_RUNNING ${LANG_RUSSIAN} "Óñòàíîâèòåëü óæå áåæèò."
|
||||
LangString UNINSTALLER_RUNNING ${LANG_RUSSIAN} "Óñòàíîâèòåëü óæå áåæèò."
|
||||
LangString ALREADY_INSTALLED ${LANG_RUSSIAN} "${product_name} óæå óñòàíîâëåíî. Óñòàíîâèòå ýòîò ïàêåò overwrite existing àðõèâû. \
|
||||
Âû õîòèòå ïðîäîëæàòü?"
|
||||
|
|
@ -1,31 +0,0 @@
|
|||
;Additional text definitions for Spanish
|
||||
;These text definition have been translated from English using an automated translation tool
|
||||
;Please correct as required
|
||||
|
||||
;file name of license file
|
||||
LicenseLangString MUILicense ${LANG_SPANISH} "..\COPYRIGHT.txt"
|
||||
|
||||
;component option
|
||||
LangString TITLE_SEC01 ${LANG_SPANISH} "Uso principal"
|
||||
LangString TITLE_SEC02 ${LANG_SPANISH} "Bibliotecas y componentes"
|
||||
LangString TITLE_SEC03 ${LANG_SPANISH} "Proyectos de Demostration"
|
||||
LangString TITLE_SEC04 ${LANG_SPANISH} "Archivos de la ayuda"
|
||||
|
||||
;component option descriptions
|
||||
LangString DESC_SEC01 ${LANG_SPANISH} "Archivos del uso principal."
|
||||
LangString DESC_SEC02 ${LANG_SPANISH} "Se requieren las bibliotecas y los componentes a menos que hayan estado instaladas previamente."
|
||||
LangString DESC_SEC03 ${LANG_SPANISH} "Algunos proyectos y clases particulares del demostration."
|
||||
LangString DESC_SEC04 ${LANG_SPANISH} "Archivos de la ayuda."
|
||||
|
||||
;warning messages
|
||||
LangString WINGS3D_PROMPT ${LANG_SPANISH} "Para corregir o crear modelos del objeto 3D que usted necesita instalar Wings3D. \
|
||||
Wings3D y el manual de usuario pueden ser transferencia directa libremente del Web page de Wings3D. Compruebe esta caja \
|
||||
para abrir el Web page de Wings3D."
|
||||
|
||||
LangString UNINST_PROMPT ${LANG_SPANISH} "¿Es usted seguro usted desea quitar totalmente $(^name) y todos sus componentes? $\n\
|
||||
Esto también quitará todos los archivos, bibliotecas y módulos modificados y nuevos en el directorio del programa."
|
||||
|
||||
LangString UNINST_SUCCESS ${LANG_SPANISH} "$(^Name) fue quitado con éxito de su computadora."
|
||||
LangString INSTALLER_RUNNING ${LANG_SPANISH} "El instalador está funcionando ya."
|
||||
LangString UNINSTALLER_RUNNING ${LANG_SPANISH} "El uninstaller está funcionando ya."
|
||||
LangString ALREADY_INSTALLED ${LANG_SPANISH} "${product_name} está instalado ya. Instale este paquete sobreescribirá archivos existentes. ¿Usted desea continuar?"
|
||||
Binary file not shown.
|
Before Width: | Height: | Size: 3.6 KiB |
|
|
@ -1,304 +0,0 @@
|
|||
; Installation script for KiCad generated by Alastair Hoyle
|
||||
;
|
||||
; This installation script requires NSIS (Nullsoft Scriptable Install System) version 2.18 http://nsis.sourceforge.net/Main_Page
|
||||
; This script was created with HM NIS Edit version 2.0.3 http://hmne.sourceforge.net/
|
||||
;
|
||||
; This script is provided as is with no warranties and has only been tested on Windows XP.
|
||||
; Copyright (C) 2006 Alastair Hoyle <ahoyle@hoylesolutions.co.uk>
|
||||
; This program is free software; you can redistribute it and/or modify it under the terms of the
|
||||
; GNU General Public License as published by the Free Software Foundation. This program is distributed
|
||||
; in the hope that it will be useful, but WITHOUT ANY WARRANTY; without even the implied warranty of
|
||||
; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License for more details.
|
||||
;
|
||||
; This script should be in a subdirectory of the full build directory (Kicad/NSIS by default)
|
||||
; When the build is updated the product and installer versions should be updated before recompiling the installation file
|
||||
;
|
||||
; This script expects the install.ico, uninstall.ico, language and license files to be in the same directory as this script
|
||||
|
||||
; General Product Description Definitions
|
||||
!define PRODUCT_NAME "KiCad"
|
||||
!define PRODUCT_VERSION "2014.03.05"
|
||||
!define ALT_DOWNLOAD_WEB_SITE "http://iut-tice.ujf-grenoble.fr/kicad/"
|
||||
!define LIBRARIES_WEB_SITE "https://github.com/KiCad/"
|
||||
!define KICAD_MAIN_SITE "www.kicad-pcb.org/"
|
||||
!define COMPANY_NAME ""
|
||||
!define TRADE_MARKS ""
|
||||
!define COPYRIGHT "Kicad Developers Team"
|
||||
!define COMMENTS ""
|
||||
!define HELP_WEB_SITE "http://groups.yahoo.com/group/kicad-users/"
|
||||
!define DEVEL_WEB_SITE "https://launchpad.net/kicad/"
|
||||
!define WINGS3D_WEB_SITE "http://www.wings3d.com"
|
||||
|
||||
!define PRODUCT_UNINST_KEY "Software\Microsoft\Windows\CurrentVersion\Uninstall\${PRODUCT_NAME}"
|
||||
!define UNINST_ROOT "HKLM"
|
||||
|
||||
|
||||
;Comment out the following SetCompressor command while testing this script
|
||||
;SetCompressor /final /solid lzma
|
||||
|
||||
CRCCheck force
|
||||
XPStyle on
|
||||
Name "${PRODUCT_NAME} ${PRODUCT_VERSION}"
|
||||
OutFile "${PRODUCT_NAME}_stable-${PRODUCT_VERSION}-BZR4xxx_Win_full_version.exe"
|
||||
;InstallDir "$PROGRAMFILES\KiCad"
|
||||
InstallDir "C:\KiCad"
|
||||
ShowInstDetails hide
|
||||
ShowUnInstDetails hide
|
||||
|
||||
; MUI 1.67 compatible ------
|
||||
!include "MUI.nsh"
|
||||
|
||||
; MUI Settings
|
||||
!define MUI_ABORTWARNING
|
||||
!define MUI_ICON "install.ico"
|
||||
!define MUI_UNICON "uninstall.ico"
|
||||
|
||||
; Language Selection Dialog Settings
|
||||
!define MUI_LANGDLL_REGISTRY_ROOT "${UNINST_ROOT}"
|
||||
!define MUI_LANGDLL_REGISTRY_KEY "${PRODUCT_UNINST_KEY}"
|
||||
!define MUI_LANGDLL_REGISTRY_VALUENAME "NSIS:Language"
|
||||
|
||||
; Installer pages
|
||||
!define MUI_CUSTOMFUNCTION_GUIINIT myGuiInit
|
||||
!define MUI_CUSTOMFUNCTION_UNGUIINIT un.myGuiInit
|
||||
!insertmacro MUI_PAGE_WELCOME
|
||||
!insertmacro MUI_PAGE_LICENSE $(MUILicense)
|
||||
!insertmacro MUI_PAGE_COMPONENTS
|
||||
!insertmacro MUI_PAGE_DIRECTORY
|
||||
!insertmacro MUI_PAGE_INSTFILES
|
||||
!define MUI_FINISHPAGE_SHOWREADME ${WINGS3D_WEB_SITE}
|
||||
!define MUI_FINISHPAGE_SHOWREADME_TEXT "text"
|
||||
!define MUI_FINISHPAGE_SHOWREADME_NOTCHECKED
|
||||
!define MUI_PAGE_CUSTOMFUNCTION_PRE ModifyFinishPage
|
||||
!insertmacro MUI_PAGE_FINISH
|
||||
|
||||
; Uninstaller pages
|
||||
!insertmacro MUI_UNPAGE_INSTFILES
|
||||
|
||||
; Language files
|
||||
; - To add another language; add an insert macro line here and include a language file as below
|
||||
; - This must be after all page macros have been inserted
|
||||
!insertmacro MUI_LANGUAGE "English" ;first language is the default language
|
||||
!insertmacro MUI_LANGUAGE "French"
|
||||
!insertmacro MUI_LANGUAGE "Italian"
|
||||
!insertmacro MUI_LANGUAGE "Polish"
|
||||
!insertmacro MUI_LANGUAGE "Portuguese"
|
||||
!insertmacro MUI_LANGUAGE "Dutch"
|
||||
!insertmacro MUI_LANGUAGE "Russian"
|
||||
!insertmacro MUI_LANGUAGE "Japanese"
|
||||
|
||||
!include "English.nsh"
|
||||
!include "French.nsh"
|
||||
!include "Dutch.nsh"
|
||||
!include "Italian.nsh"
|
||||
!include "Japanese.nsh"
|
||||
!include "Polish.nsh"
|
||||
!include "Portuguese.nsh"
|
||||
!include "Russian.nsh"
|
||||
|
||||
; MUI end ------
|
||||
|
||||
Function .onInit
|
||||
ReserveFile "install.ico"
|
||||
ReserveFile "uninstall.ico"
|
||||
ReserveFile "${NSISDIR}\Plugins\InstallOptions.dll"
|
||||
ReserveFile "${NSISDIR}\Plugins\LangDLL.dll"
|
||||
ReserveFile "${NSISDIR}\Plugins\System.dll"
|
||||
ReserveFile "${NSISDIR}\Contrib\Modern UI\ioSpecial.ini"
|
||||
!insertmacro MUI_LANGDLL_DISPLAY
|
||||
FunctionEnd
|
||||
|
||||
Function myGuiInit
|
||||
Call PreventMultiInstances
|
||||
Call CheckAlreadyInstalled
|
||||
FunctionEnd
|
||||
|
||||
Function ModifyFinishPage
|
||||
!insertmacro MUI_INSTALLOPTIONS_WRITE "ioSpecial.ini" "Field 4" "Text" $(WINGS3D_PROMPT)
|
||||
!insertmacro MUI_INSTALLOPTIONS_WRITE "ioSpecial.ini" "Field 4" "Bottom" 168 ;make more space for prompt
|
||||
!insertmacro MUI_INSTALLOPTIONS_WRITE "ioSpecial.ini" "Settings" "CancelShow" "0" ;hide cancel button - already installed!!
|
||||
FunctionEnd
|
||||
|
||||
Section $(TITLE_SEC01) SEC01
|
||||
SectionIn RO
|
||||
SetOverwrite try
|
||||
SetOutPath "$INSTDIR"
|
||||
File /nonfatal "..\AUTHORS.txt"
|
||||
File /nonfatal "..\COPYRIGHT.txt"
|
||||
File /nonfatal "..\license_for_documentation.txt"
|
||||
SetOutPath "$INSTDIR\share\kicad\template"
|
||||
File /nonfatal /r "..\share\kicad\template\*"
|
||||
SetOutPath "$INSTDIR\bin"
|
||||
File /r "..\bin\*"
|
||||
SetOutPath "$INSTDIR\share\kicad\internat"
|
||||
File /r "..\share\kicad\internat\*"
|
||||
SectionEnd
|
||||
|
||||
Section $(TITLE_SEC02) SEC02
|
||||
SetOverwrite try
|
||||
SetOutPath "$INSTDIR\share\library"
|
||||
File /nonfatal /r "..\share\library\*"
|
||||
SetOutPath "$INSTDIR\share\modules"
|
||||
File /nonfatal /r "..\share\modules\*"
|
||||
SectionEnd
|
||||
|
||||
Section $(TITLE_SEC03) SEC03
|
||||
SetOverwrite try
|
||||
SetOutPath "$INSTDIR\share\kicad\demos"
|
||||
File /nonfatal /r "..\share\kicad\demos\*"
|
||||
SetOutPath "$INSTDIR\share\doc\kicad\tutorials"
|
||||
File /nonfatal /r "..\share\doc\kicad\tutorials\*"
|
||||
SectionEnd
|
||||
|
||||
Section $(TITLE_SEC04) SEC04
|
||||
SetOverwrite try
|
||||
SetOutPath "$INSTDIR\share\doc\kicad\help"
|
||||
File /nonfatal /r "..\share\doc\kicad\help\*"
|
||||
SectionEnd
|
||||
|
||||
Section -CreateShortcuts
|
||||
SetOutPath $INSTDIR
|
||||
WriteIniStr "$INSTDIR\HomePage.url" "InternetShortcut" "URL" "${KICAD_MAIN_SITE}"
|
||||
WriteIniStr "$INSTDIR\AltDownloadSite.url" "InternetShortcut" "URL" "${ALT_DOWNLOAD_WEB_SITE}"
|
||||
WriteIniStr "$INSTDIR\UserGroup.url" "InternetShortcut" "URL" "${HELP_WEB_SITE}"
|
||||
WriteIniStr "$INSTDIR\DevelGroup.url" "InternetShortcut" "URL" "${DEVEL_WEB_SITE}"
|
||||
WriteIniStr "$INSTDIR\LibrariesGroup.url" "InternetShortcut" "URL" "${LIBRARIES_WEB_SITE}"
|
||||
WriteIniStr "$INSTDIR\Wings3D.url" "InternetShortcut" "URL" "${WINGS3D_WEB_SITE}"
|
||||
SetShellVarContext all
|
||||
CreateDirectory "$SMPROGRAMS\KiCad"
|
||||
CreateShortCut "$SMPROGRAMS\KiCad\Home Page.lnk" "$INSTDIR\HomePage.url"
|
||||
CreateShortCut "$SMPROGRAMS\KiCad\Kicad Alternate Download.lnk" "$INSTDIR\AltDownloadSite.url"
|
||||
CreateShortCut "$SMPROGRAMS\KiCad\Kicad Libraries.lnk" "$INSTDIR\LibrariesGroup.url"
|
||||
CreateShortCut "$SMPROGRAMS\KiCad\Wings3D.lnk" "$INSTDIR\Wings3D.url"
|
||||
CreateShortCut "$SMPROGRAMS\KiCad\User Group.lnk" "$INSTDIR\UserGroup.url"
|
||||
CreateShortCut "$SMPROGRAMS\KiCad\Devel Group.lnk" "$INSTDIR\DevelGroup.url"
|
||||
CreateShortCut "$SMPROGRAMS\KiCad\Uninstall.lnk" "$INSTDIR\uninstaller.exe"
|
||||
CreateShortCut "$SMPROGRAMS\KiCad\KiCad.lnk" "$INSTDIR\bin\kicad.exe"
|
||||
CreateShortCut "$DESKTOP\KiCad.lnk" "$INSTDIR\bin\kicad.exe"
|
||||
SectionEnd
|
||||
|
||||
Section -CreateAddRemoveEntry
|
||||
WriteRegStr ${UNINST_ROOT} "${PRODUCT_UNINST_KEY}" "DisplayName" "$(^Name)"
|
||||
WriteRegStr ${UNINST_ROOT} "${PRODUCT_UNINST_KEY}" "DisplayVersion" "${PRODUCT_VERSION}"
|
||||
WriteRegStr ${UNINST_ROOT} "${PRODUCT_UNINST_KEY}" "Publisher" "${COMPANY_NAME}"
|
||||
WriteRegStr ${UNINST_ROOT} "${PRODUCT_UNINST_KEY}" "UninstallString" "$INSTDIR\uninstaller.exe"
|
||||
WriteRegStr ${UNINST_ROOT} "${PRODUCT_UNINST_KEY}" "URLInfoAbout" "${KICAD_MAIN_SITE}"
|
||||
WriteRegStr ${UNINST_ROOT} "${PRODUCT_UNINST_KEY}" "DisplayIcon" "$INSTDIR\bin\kicad.exe"
|
||||
WriteRegDWORD ${UNINST_ROOT} "${PRODUCT_UNINST_KEY}" "NoModify" "1"
|
||||
WriteRegDWORD ${UNINST_ROOT} "${PRODUCT_UNINST_KEY}" "NoRepair" "1"
|
||||
WriteRegStr ${UNINST_ROOT} "${PRODUCT_UNINST_KEY}" "Comments" "${COMMENTS}"
|
||||
WriteRegStr ${UNINST_ROOT} "${PRODUCT_UNINST_KEY}" "HelpLink" "${HELP_WEB_SITE}"
|
||||
WriteRegStr ${UNINST_ROOT} "${PRODUCT_UNINST_KEY}" "URLUpdateInfo" "${KICAD_MAIN_SITE}"
|
||||
WriteRegStr ${UNINST_ROOT} "${PRODUCT_UNINST_KEY}" "InstallLocation" "$INSTDIR"
|
||||
|
||||
WriteUninstaller "$INSTDIR\uninstaller.exe"
|
||||
SectionEnd
|
||||
|
||||
!insertmacro MUI_FUNCTION_DESCRIPTION_BEGIN
|
||||
!insertmacro MUI_DESCRIPTION_TEXT ${SEC01} $(DESC_SEC01)
|
||||
!insertmacro MUI_DESCRIPTION_TEXT ${SEC02} $(DESC_SEC02)
|
||||
!insertmacro MUI_DESCRIPTION_TEXT ${SEC03} $(DESC_SEC03)
|
||||
!insertmacro MUI_DESCRIPTION_TEXT ${SEC04} $(DESC_SEC04)
|
||||
!insertmacro MUI_FUNCTION_DESCRIPTION_END
|
||||
|
||||
Function un.onInit
|
||||
!insertmacro MUI_UNGETLANGUAGE
|
||||
FunctionEnd
|
||||
|
||||
Function un.myGuiInit
|
||||
Call un.PreventMultiInstances
|
||||
MessageBox MB_ICONEXCLAMATION|MB_YESNO|MB_DEFBUTTON2 $(UNINST_PROMPT) /SD IDYES IDYES +2
|
||||
Abort
|
||||
FunctionEnd
|
||||
|
||||
Function un.onUninstSuccess
|
||||
HideWindow
|
||||
MessageBox MB_ICONINFORMATION|MB_OK $(UNINST_SUCCESS) /SD IDOK
|
||||
FunctionEnd
|
||||
|
||||
Section Uninstall
|
||||
;delete uninstaller first
|
||||
Delete "$INSTDIR\uninstaller.exe"
|
||||
|
||||
;remove start menu shortcuts and web page links
|
||||
SetShellVarContext all
|
||||
Delete "$SMPROGRAMS\KiCad\Home Page.lnk"
|
||||
Delete "$SMPROGRAMS\KiCad\Kicad Libraries.lnk"
|
||||
Delete "$SMPROGRAMS\KiCad\Kicad Alternate Download.lnk"
|
||||
Delete "$SMPROGRAMS\KiCad\Devel Group.lnk"
|
||||
Delete "$SMPROGRAMS\KiCad\User Group.lnk"
|
||||
Delete "$SMPROGRAMS\KiCad\Uninstall.lnk"
|
||||
Delete "$SMPROGRAMS\KiCad\KiCad.lnk"
|
||||
Delete "$SMPROGRAMS\KiCad\Wings3D.lnk"
|
||||
Delete "$DESKTOP\KiCad.lnk"
|
||||
Delete "$INSTDIR\Wings3D.url"
|
||||
Delete "$INSTDIR\HomePage.url"
|
||||
Delete "$INSTDIR\UserGroup.url"
|
||||
Delete "$INSTDIR\AltDownloadSite.url"
|
||||
Delete "$INSTDIR\DevelGroup.url"
|
||||
Delete "$INSTDIR\LibrariesGroup.url"
|
||||
RMDir "$SMPROGRAMS\KiCad"
|
||||
|
||||
;remove all program files now
|
||||
RMDir /r "$INSTDIR\bin"
|
||||
RMDir /r "$INSTDIR\library"
|
||||
RMDir /r "$INSTDIR\modules"
|
||||
RMDir /r "$INSTDIR\template"
|
||||
RMDir /r "$INSTDIR\internat"
|
||||
RMDir /r "$INSTDIR\demos"
|
||||
RMDir /r "$INSTDIR\tutorials"
|
||||
RMDir /r "$INSTDIR\help"
|
||||
RMDir /r "$INSTDIR\share\library"
|
||||
RMDir /r "$INSTDIR\share\modules"
|
||||
RMDir /r "$INSTDIR\share\kicad\template"
|
||||
RMDir /r "$INSTDIR\share\kicad\internat"
|
||||
RMDir /r "$INSTDIR\share\kicad\demos"
|
||||
RMDir /r "$INSTDIR\share\doc\kicad\tutorials"
|
||||
RMDir /r "$INSTDIR\share\doc\kicad\help"
|
||||
RMDir /r "$INSTDIR\wings3d"
|
||||
;don't remove $INSTDIR recursively just in case the user has installed it in c:\ or
|
||||
;c:\program files as this would attempt to delete a lot more than just this package
|
||||
Delete "$INSTDIR\*.txt"
|
||||
RMDir "$INSTDIR"
|
||||
|
||||
;Note - application registry keys are stored in the users individual registry hive (HKCU\Software\kicad".
|
||||
;It might be possible to remove these keys as well but it would require a lot of testing of permissions
|
||||
;and access to other people's registry entries. So for now we will leave the application registry keys.
|
||||
|
||||
;remove installation registary keys
|
||||
DeleteRegKey ${UNINST_ROOT} "${PRODUCT_UNINST_KEY}"
|
||||
SetAutoClose true
|
||||
SectionEnd
|
||||
|
||||
;Setup.exe file version information
|
||||
VIProductVersion "${PRODUCT_VERSION}.01" ;must be in x.x.x.x format - product version plus last digit for installer version number
|
||||
VIAddVersionKey /LANG=${LANG_ENGLISH} "ProductName" "${PRODUCT_NAME}"
|
||||
VIAddVersionKey /LANG=${LANG_ENGLISH} "Comments" "${COMMENTS}"
|
||||
VIAddVersionKey /LANG=${LANG_ENGLISH} "CompanyName" "${COMPANY_NAME}"
|
||||
VIAddVersionKey /LANG=${LANG_ENGLISH} "LegalTrademarks" "${TRADE_MARKS}"
|
||||
VIAddVersionKey /LANG=${LANG_ENGLISH} "LegalCopyright" "© ${COPYRIGHT}"
|
||||
VIAddVersionKey /LANG=${LANG_ENGLISH} "FileDescription" "${PRODUCT_NAME} Installer"
|
||||
VIAddVersionKey /LANG=${LANG_ENGLISH} "FileVersion" "${PRODUCT_VERSION}"
|
||||
|
||||
Function PreventMultiInstances
|
||||
System::Call 'kernel32::CreateMutexA(i 0, i 0, t "myMutex") i .r1 ?e'
|
||||
Pop $R0
|
||||
StrCmp $R0 0 +3
|
||||
MessageBox MB_OK|MB_ICONEXCLAMATION $(INSTALLER_RUNNING) /SD IDOK
|
||||
Abort
|
||||
FunctionEnd
|
||||
|
||||
Function un.PreventMultiInstances
|
||||
System::Call 'kernel32::CreateMutexA(i 0, i 0, t "myMutex") i .r1 ?e'
|
||||
Pop $R0
|
||||
StrCmp $R0 0 +3
|
||||
MessageBox MB_OK|MB_ICONEXCLAMATION $(UNINSTALLER_RUNNING) /SD IDOK
|
||||
Abort
|
||||
FunctionEnd
|
||||
|
||||
Function CheckAlreadyInstalled
|
||||
ReadRegStr $R0 ${UNINST_ROOT} "${PRODUCT_UNINST_KEY}" "DisplayName"
|
||||
StrCmp $R0 "" +3
|
||||
MessageBox MB_OKCANCEL|MB_ICONEXCLAMATION $(ALREADY_INSTALLED) /SD IDOK IDOK +2
|
||||
Abort
|
||||
FunctionEnd
|
||||
Binary file not shown.
|
Before Width: | Height: | Size: 3.6 KiB |
Loading…
Reference in New Issue