racket-nix/flake.nix

{
  description = "Flake for racket packaging test";

  outputs = { self, dragnpkgs } @ inputs: {
    legacyPackages.x86_64-linux = dragnpkgs.lib.dragnpkgs-custom {
      system = "x86_64-linux";
      overlays = [self.overlays.default];
    };

    overlays.default = final: prev: {
      racket-minimal = final.callPackage ./racket/minimal.nix {};
      racket = final.callPackage ./racket/package.nix {};

      racketPackages = final.lib.makeScope final.newScope (self: {
        racketInstallHook = self.callPackage ./racket-install-hook.nix {};
        buildRacketPackage = self.callPackage ./build-racket-package.nix {};

        makeRacketEnv = self.callPackage ./make-racket-env.nix {};

        testEnv = self.makeRacketEnv {
          packages = [self.ansi-color];
        };

        ansi-color = self.callPackage (
          {
            lib,
            buildRacketPackage,
            fetchFromGitHub,
          }: buildRacketPackage {
            pname = "ansi-color";
            version = "0.2";

            src = final.fetchFromGitHub {
              owner = "renatoathaydes";
              repo = "ansi-color";
              rev = "0.2";
              hash = "sha256-7WDW+4R9K+XLb9nMNGQlU+zAi2Gq7cUqzO3csN+AJvI=";
            };
          }
        ) {};

        namespaced-transformer-lib = self.callPackage (
          {
            lib,
            buildRacketPackage,
            fetchFromGitHub,
          }: buildRacketPackage {
            pname = "namespaced-transformer-lib";
            version = "none";

            src = "${final.fetchFromGitHub {
              owner = "lexi-lambda";
              repo = "namespaced-transformer";
              rev = "4cdc1bdae09a07b78f23665267f2c7df4be5a7f6";
              hash = "sha256-vpDJ7qUNhKreig1LbU33d7TXXHkfd7gPxE1Fc5bvzFE=";
            }}/namespaced-transformer-lib";
          }
        ) {};

        curly-fn-lib = self.callPackage (
          {
            lib,
            buildRacketPackage,
            fetchFromGitHub,

            namespaced-transformer-lib,
          }: buildRacketPackage {
            pname = "curly-fn-lib";
            version = "none";

            dependencies = [ namespaced-transformer-lib ];

            src = "${final.fetchFromGitHub {
              owner = "lexi-lambda";
              repo = "racket-curly-fn";
              rev = "d64cd71d5b386be85f5979edae6f6b6469a4df86";
              hash = "sha256-ge7o/UAvUXA4DIl03UkqVnLHNaPGq4SqxWvpcKdXndI=";
            }}/curly-fn-lib";
          }
        ) {};

      });
    };
  };
}