nix-infra/flake.nix

{
  inputs = {
    nixpkgs.url = "nixpkgs/nixos-22.11";

    home-manager = {
      url = "github:nix-community/home-manager";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    mms = {
      url = "github:mkaito/nixos-modded-minecraft-servers";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    url-eater.url = "github:AgathaSorceress/url-eater";

    colorpickle.url = "github:AgathaSorceress/colorpickle";

    # Latest colmena + prettier loading icons
    colmena.url = "github:AgathaSorceress/colmena";

    frq-friend.url = "git+https://git.xenua.me/xenua/fedi-frq-friend";
    vampysite.url = "git+https://git.lain.faith/sorceress/vampysite";

    helix.url = "github:helix-editor/helix";
  };
  outputs = { nixpkgs, home-manager, mms, helix, url-eater, colorpickle
    , frq-friend, colmena, vampysite, ... }: {
      colmena = {
        network = {
          description = "Agatha's Nix Infra";

          nixpkgs = import nixpkgs {
            system = "x86_64-linux";
            overlays = [
              (final: prev: {
                helix = helix.packages.${final.system}.default;
                colorpickle = colorpickle.packages.${final.system}.default;
                frq-friend = frq-friend.defaultPackage.${final.system};
                vampysite = vampysite.packages.${final.system}.default;
              })
              colmena.overlay
            ];
          };
        };

        bloodletting = {
          imports = [
            ./common
            ./hosts/bloodletting/configuration.nix
            (import "${home-manager}/nixos")
            mms.module
          ];

          deployment = {
            targetUser = "root";
            targetHost = "bloodletting";

            tags = [ "prod" ];

            keys = {
              "nyandroid-token" = {
                keyCommand = [ "cat" "./secrets/nyandroid-token" ];
                destDir = "/var/lib/secrets/";
              };
              "rfc2136-technogothic-net" = {
                keyCommand = [ "cat" "./secrets/rfc2136-technogothic-net" ];
                destDir = "/var/lib/secrets/";
              };
              "fedi-data.toml" = {
                keyCommand = [ "cat" "./secrets/frq-friend-fedi-data.toml" ];
                destDir = "/var/lib/frq-friend";
              };
            };
          };
        };

        ritual = {
          imports = [
            ./common
            ./hosts/ritual/configuration.nix
            (import "${home-manager}/nixos")
            url-eater.nixosModule
            colorpickle.nixosModules.default
          ];

          deployment = {
            targetUser = "root";
            targetHost = "ritual";

            allowLocalDeployment = true;
          };
        };
      };
      devShells."x86_64-linux".default =
        let pkgs = import nixpkgs { system = "x86_64-linux"; };
        in pkgs.mkShell {
          buildInputs = [
            (pkgs.writeShellScriptBin "colmena" ''
              ${
                colmena.defaultPackage.${pkgs.system}
              }/bin/colmena --disable-emoji $@
            '')
          ];
        };
    };
}