dragnpkgs/overlay.nix

final: prev: {
  lib = prev.lib.extend (lfinal: lprev: {
    licenses = lprev.licenses // { fyptl = import ./lib/licenses/fyptl.nix; };
  });

  fetchFromSteam = prev.callPackage ./lib/fetchsteam {};
  fetchb4 = prev.callPackage ./lib/fetchb4 {};

  gitSource = prev.callPackage ./lib/git-source {};

  makeSquashFs = prev.callPackage ./lib/make-squashfs {};
  makeHpcDist = final.callPackage ./lib/make-hpc-dist {};

  ghidra_headless = final.ghidra.lib;

  # stuff that tracks upstream
  ghidra = final.callPackage ./pkgs/ghidra-xenia-v2/build.nix {
    protobuf = final.protobuf_21;
  };
  ghidra-extensions = final.lib.recurseIntoAttrs (final.callPackage ./pkgs/ghidra-xenia-v2/extensions.nix { });
  # end stuff that tracks upstream


  ocamlPackages = prev.ocamlPackages.overrideScope (ofinal: oprev: {
    ppx_unicode = ofinal.callPackage ./pkgs/ocaml/ppx_unicode {};
    xlog = ofinal.callPackage ./pkgs/ocaml/xlog {};
    systemd-ml = ofinal.callPackage ./pkgs/ocaml/systemd-ml {};

    ocaml-manual = ofinal.callPackage ./pkgs/ocaml/ocaml-manual {};
  });

  python3Packages = prev.python3Packages.overrideScope (pfinal: pprev: {
    feedvalidator = pfinal.callPackage ./pkgs/python/feedvalidator {};
  });

  # add to top level because it has a binary
  feedvalidator = final.python3Packages.feedvalidator;

  outer-wilds-text-adventure = prev.callPackage ./pkgs/games/outer-wilds-text-adventure {};

  mkNginxServer = prev.callPackage ./lib/dev-nginx {};

  zbasefind = final.callPackage ./pkgs/rust/zbasefind {};

  eta = prev.callPackage ./pkgs/cmdline/eta {};

  cado-nfs = prev.callPackage ./pkgs/crypto/cado-nfs {};

  lix-plugins = prev.callPackage ./pkgs/lix/lix-plugins {};
  nix-plugins = builtins.throw "nix-plugins is not supported. see pkgs.lix-plugins";

  zfs_2_2 = prev.zfs_2_2.overrideAttrs {
    patches = [ ./pkgs/zfs/0001-ZED-add-support-for-desktop-notifications-D-Bus.patch ];
  };
}